#! /usr/bin/perl -w
#
# Copyright 2001-2003  August Hoerandl (august.hoerandl@gmx.at)
#                 http://elina.htlw16.ac.at/~hoerandl
#
# This program is free software.  You can redistribute it and/or modify
# it under the terms of the GNU General Public License 
#
# create config from database
#  dhcpd.conf
#  named forward + reverse
#
# 1) one entry for each dhcp client 
#  ip addr,      name,      mac,             comment 
# 172.16.10.17, ws231-a1, 00:05:04:03:02:01, whatever
#
# you may use a mac 00:00 for to get an entry into dns but
#  no dhcp entry
#
# 2) one line for each cname (hostname alias)
#  CNAME, name, original name
#  CNAME, time, ns
#
# the server is assumed to be named ns (but may have some cnames)
#
# for newer dhcpd versions use
#   -dhcpopt "ddns-update-style none;"
# 
# History
#  0.1   3/2001    initial version
#  0.2             added subnetmask detection
#  0.21            added params
#  0.25            added $cnamefile
#  0.30 11/2001    added ARP
#  0.31    2003    cleanup
         
$version = "0.31";

$database   = "./admin.dat";      # Name of db file.
$cnamefile = "./cname.dat";       # additional db file - optional

$all_file = "all";
$arp_file = "arp.set";

$debug = 0;

$dhcp_file = "dhcpd.conf";

$domain = "htlw16.ac.at";
$dhcp_domain_name = "itz.$domain";
$dhcp_domain_name_servers = "172.16.1.75, 172.16.1.70, 172.16.1.44";
$dhcp_range = "172.16.3.10 172.16.3.250";

$dhcpopt = "";

#guessed: $dhcp_subnet_mask = "255.255.0.0";
#guessed $dhcp_broadcast_address = "172.16.255.255";
$dhcp_time_servers = "time.$dhcp_domain_name";
$dhcp_font_servers = "fs.$dhcp_domain_name";

$forw_file = "$dhcp_domain_name";
#guessed: $rev_file = "16.172.in-addr.arpa";

$dhcp_to = 3600*10;
$dhcp_to_fix = 10*$dhcp_to;

$dhcp_to_max = 4*$dhcp_to;
$dhcp_to_max_fix = 4*$dhcp_to_fix;

$bindto = $dhcp_to_fix;

# ------------------------------------------------------------------
use Getopt::Long;

# ------------------------------------------------------------------

$mask1 = 0;
$mask2 = 0;
$mask3 = 0;
$mask4 = 0;


sub do_read {

  while ($line = <DB>) {
    print "." if $debug;
    chop $line;
    next if ($line =~ /^\#/);

    if ($line =~ /^CNAME/) {
      ($cbname, $name, $org) = split(/,/, $line);
      $cbname = "";
      $name =~ s/ //;
      $cname{$name} = $org;
      next;
    }
    $host = "";
    ($addr, $host, $mac, $comm) = split(/,/, $line);
    next if (! $host);
    $mac =~ y/a-z/A-Z/;   # mac uppercase
    $host =~ y/A-Z/a-z/;  # hostname lowercase
    $host =~ s/ //;
    print "read $host ($addr)\n" if $debug;
    $hostname{$addr} = $host;
    $macaddr{$addr} = $mac;
    $comment{$addr} = $comm;

    ($sub1,$sub2,$sub3,$sub4) = split(/\./, $addr);
    $subnet{"$sub1.$sub2.$sub3"} ++;
    $mask1 |= $sub1;
    $mask2 |= $sub2;
    $mask3 |= $sub3;
    $mask4 |= $sub4;
    print " subnet $sub1.$sub2.$sub3 (.$sub4)\n" if $debug;
  }
}

sub read_database {

  print "open database $database\n" if $debug;
  open(DB,"<$database") ||
    die ("Can't open $database; $!");

  &do_read;

  close DB;

  print "open database $cnamefile\n" if $debug;
  open(DB,"<$cnamefile") && &do_read;
  close DB;

  if ($debug) {
    foreach $sn (keys (%subnet)) {
      print "$sn count $subnet{$sn}\n";
    }
  }

}
# ------------------------------------------------------------------

sub guess_nw {

  if ($mask1 == $sub1) {
    $class = 1 ;
#    $dhcp_network = "$mask1.0.0.0";
#    $dhcp_subnet_mask = "255.0.0.0";
#    $dhcp_broadcast_address = "$mask1.255.255.255";
    $rev_file =  "$mask1.in-addr.arpa";

    $dhcp_network = "$mask1.0.0.0";
    $dhcp_subnet_mask = "255.0.0.0";
    $dhcp_broadcast_address = "$mask1.255.255.255";

  }

  if ($mask2 == $sub2) {
    $class = 2;
    $dhcp_network = "$mask1.$mask2.0.0";
    $dhcp_subnet_mask = "255.255.0.0";
    $dhcp_broadcast_address = "$mask1.$mask2.255.255";
    $rev_file =  "$mask2.$mask1.in-addr.arpa"
  }

  if ($mask3 == $sub3) {
    $class = 3;
    $dhcp_network = "$mask1.$mask2.$mask3.0";
    $dhcp_subnet_mask = "255.255.255.0";
    $dhcp_broadcast_address = "$mask1.$mask2.$mask3.255";
    $rev_file =  "$mask3.$mask2.$mask1.in-addr.arpa"
  }

  $dhcp_router = $dhcp_network;
  $dhcp_router =~ s/0$/1/;

  print "\nMask: $mask1.$mask2.$mask3.$mask4 ($class)\n" if $debug;
  print "   $dhcp_subnet_mask $dhcp_broadcast_address $dhcp_router $rev_file\n" if $debug;
}


# ------------------------------------------------------------------
# ------------------------------------------------------------------

# unused: convert dhcp file to database
sub dump_old_dhcp {
  while ($line = <STDIN>) {
    if ($line =~ /host ([a-zA-Z0-9_-]*)/) {
      $host = $1;
    }
    if ($line =~ /hardware ethernet *(..:..:..:..:..:..)/) {
      $mac = $1;
    }
    if ($line =~ /fixed-address *([0-9.]*)/) {
      $addr = $1;
      print "$addr, $host, $mac, -\n" if ($host);
      $host = "";
      $mac = "";
    }
  }
}

# ------------------------------------------------------------------

sub dump_dhcp {
  print "\nopen $dhcp_file\n" if $debug;
  open(DHCP,">$dhcp_file") ||
    die ("Can't open $dhcp_file; $!");

  print DHCP <<EOF;
# dhcpd.conf
#
# Configuration file for ISC dhcpd
#
server-identifier ns.$dhcp_domain_name;

#option definitions common to all supported networks...

option domain-name "$dhcp_domain_name";
option domain-name-servers $dhcp_domain_name_servers;
option subnet-mask $dhcp_subnet_mask;
option broadcast-address $dhcp_broadcast_address;

#deny unknown-clients;
authoritative;

use-host-decl-names on;
option time-servers $dhcp_time_servers;
option font-servers $dhcp_font_servers;

default-lease-time $dhcp_to_fix;
max-lease-time $dhcp_to_max_fix;

$dhcpopt

subnet  $dhcp_network netmask  $dhcp_subnet_mask {
  default-lease-time $dhcp_to;
  max-lease-time $dhcp_to_max;
  range $dhcp_range;
  option routers $dhcp_router;
}

EOF

  foreach $sn (sort keys (%subnet)) {
    print DHCP "\n\ngroup { # subnet $sn\n";
    print DHCP "  option routers $sn.1;\n";
    print DHCP "  default-lease-time 36000;\n";
    print DHCP "  max-lease-time     72000;\n";
    foreach $addr (sort keys (%hostname)) {
#      next if ($macaddr{$addr} eq "00:00");
      next unless ($macaddr{$addr} =~ "..:..:..:..:..:..");
      next if (index($addr, "$sn.") != 0);
      print DHCP "  host $hostname{$addr} { # $comment{$addr}\n";
      print DHCP "    hardware ethernet $macaddr{$addr}; \n";
      print DHCP "    fixed-address $addr;\n";
      print DHCP "  }\n";
    }
    print DHCP "} #  subnet $sn\n";
  }
  close DHCP;
}


# ------------------------------------------------------------------

sub dump_named_forw {
  print "\nopen $forw_file\n" if $debug;
  open(FORW,">$forw_file") ||
    die ("Can't open $forw_file; $!");

  ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
  $serial = sprintf("%04d%02d%02d%02d", $year+1900, 1+$mon, $mday, $hour);

  print FORW <<EOF;
; BIND
\$ORIGIN $domain.
itz     $bindto   IN      SOA     ns.$dhcp_domain_name. root.ns.$dhcp_domain_name. (
                $serial 10800 3600 800000 38400 )
        $bindto   IN      NS      ns.
 
\$ORIGIN $dhcp_domain_name.
EOF

  foreach $addr (sort keys (%hostname)) {
    printf FORW "%-20s",$hostname{$addr};
    print FORW "\t$bindto\tIN	A\t$addr\n";
  }
  printf FORW "\n";
  foreach $name (sort keys (%cname)) {
    printf FORW "%-20s",$name;
    print FORW "\t$bindto\tIN	CNAME\t$cname{$name}.$dhcp_domain_name.\n";
  }
  close FORW;
}



sub dump_named_rev {
#  $rev_file = "$sub2.$sub1.in-addr.arpa";
  print "\nopen $rev_file\n" if $debug;
  open(REV,">$rev_file") ||
    die ("Can't open $rev_file; $!");

  ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
  $serial = sprintf("%04d%02d%02d%02d", $year+1900, 1+$mon, $mday, $hour);

  print REV <<EOF;
\$ORIGIN $sub1.in-addr.arpa.
$sub2      $bindto   IN      SOA     ns.$dhcp_domain_name. root.ns.$dhcp_domain_name. (
                $serial 10800 3600 800000 38400 )
        $bindto   IN      NS      ns.
EOF

  foreach $sn (sort keys (%subnet)) {
    ($s1,$s2,$s3,$s4) = split(/\./, $sn);
    $s4 = ""; # ignore
    print REV "\n\$ORIGIN $s3.$s2.$s1.in-addr.arpa.\n";

    foreach $addr (sort keys (%hostname)) {
      next if (index($addr, "$sn.") != 0);
      ($a1,$a2,$a3,$a4) = split(/\./, $addr);
      $a1=$a2=$a3= ""; # ignore
      print REV "$a4\t$bindto\tIN PTR\t$hostname{$addr}.$dhcp_domain_name.\n";
    }
  }
  close REV;
}

# ------------------------------------------------------------------

sub dump_all {
  print "\nopen $all_file\n" if $debug;
  open(ALL,">$all_file") ||
    die ("Can't open $all_file; $!");
    foreach $addr (sort keys (%hostname)) {
      print ALL "$addr\n";
    }
  close ALL;
}
# ------------------------------------------------------------------

sub dump_arp {
  print "\nopen $arp_file\n" if $debug;
  open(ARP,">$arp_file") ||
    die ("Can't open $arp_file; $!");
    foreach $addr (sort keys (%hostname)) {
      print ARP "arp -s $addr $macaddr{$addr}\n" 
           unless $macaddr{$addr} eq "00:00";
    }
  close ARP;
}
# ------------------------------------------------------------------

sub usage {
  die <<EOF;
admin.pl [options]
  create config from database / version $version
    --help           show this help
    --debug          debug ($debug)
    --database=file  database to read ($database)
    --dhcp_range     dynamic range ($dhcp_range)
    --dhcpopt        additional dhcp options($dhcpopt)
    --arp=file       filename for arp set commands ($arp_file)
EOF
} 

# ------------------------------------------------------------------
#
# program starts here
#

$res = GetOptions (
		   "help!" => \$showhelp,
		   "database=s" => \$database,
		   "debug!" => \$debug,
		   "dhcp-range=s" => \$dhcp_range,
		   "dhcpopt=s" => \$dhcpopt,
                   "arp=s" => \$arp_file,
		  );

&usage if (!$res || $showhelp || $#ARGV >= 0);
$time = time;

print "$time\n" if $debug;

#&dump_old_dhcp; exit (99);

&read_database;

&guess_nw;

&dump_dhcp;
&dump_named_forw;
&dump_named_rev;
&dump_all;
&dump_arp;